SPARQL Endpoint Service

ELSEWeb's Linked Data is managed and stored by an instance of Virtuoso's Triple Store.

Try out SPARQL queries through the Virtuoso Endpoint Service:

Click here to access

Sample Queries

The following sample queries can be directly pasted into the Virtuoso SPARQL Endpoint for execution.

Copy each sample separately to the endpoint input box and include prefixes as required.


    #prefixes

    # define the mappings to be used
    define input:inference "http://ontology.cybershare.utep.edu/ELSEWeb/elseweb-mappings-v2.owl"

    # custom ELSEWeb prefixes
    prefix elseweb-data: <http://ontology.cybershare.utep.edu/ELSEWeb/elseweb-data.owl#>
    prefix elseweb-edac: <http://ontology.cybershare.utep.edu/ELSEWeb/elseweb-edac.owl#>
    prefix lifemapper: <http://ontology.cybershare.utep.edu/ELSEWeb/elseweb-lifemapper.owl#>

    # base LOD prefixes
    prefix provo: <http://www.w3.org/ns/prov#>
    prefix dcat: <http://www.w3.org/ns/dcat#>
    prefix sio: <http://semanticscience.org/resource/>

    #Sample 1: show me all EDAC data access services serving MODIS data in terms of ELSEWeb

    select ?dataset
    {
         ?dataset a dcat:Dataset.
         ?dataset elseweb-data:hasDataBand
            [
                elseweb-edac:wasMeasuredBy
                    [
                        elseweb-edac:wasAssociatedWith <http://visko.cybershare.utep.edu/linked-data/edac/services/MODIS>
                    ]
            ]
    }

    #Sample 2: show me species name and id of species occurrence sets harvested from Lifemapper

    select ?name ?id
    from <http://ontology.cybershare.utep.edu/ELSEWeb/linked-data/lifemapper/occurrences-v2/species-occurrences-v2.owl>
    where{
        ?dataset a lifemapper:SpeciesOccurrenceDataset.
        ?dataset elseweb-data:hasLayer ?layer.
        ?dataset elseweb-data:hasManifestation ?manif.
        ?manif elseweb-data:hasFileDownloadURL ?fileURL.
        ?manif elseweb-data:hasLandingPageURL ?metadataURL.
        ?layer elseweb-data:containsFeatureSet ?set.
        ?set a lifemapper:SpeciesOccurrenceSet.
        ?set lifemapper:hasOccurrenceSetID ?id.
        ?set lifemapper:hasOccurrenceOfSpecies ?species.
        ?species lifemapper:hasGenusName ?name.
    }

    #Sample 3:show me environmental data entities available in a boxed region

    select distinct ?entity
    from <http://ontology.cybershare.utep.edu/ELSEWeb/linked-data/edac/services/wcs-services.owl>
    where
    {
        ?dataset elseweb-data:coversRegion ?region.
        ?region elseweb-data:hasLeftLongitude ?llon.
        ?region elseweb-data:hasRightLongitude ?rlon.
        ?region elseweb-data:hasLowerLatitude ?llat.
        ?region elseweb-data:hasUpperLatitude ?ulat.
        filter(?llon <= -92.28515625)
        filter(?rlon >= -72.7734375)
        filter(?llat <= 39.50404070558425)
        filter(?ulat >= 45.82879925192136)
        ?dataset elseweb-data:hasDataBand ?band.
        ?band elseweb-data:representsEntity ?entity.
    }

    #Sample 4: show me all edac data access services and metadata URLs in terms of DCAT and ELSEWeb vocabulary (uses mappings alignment with LOD ontologies)

    select ?dataset ?capabilitiesURL ?jsonURL
    {
            ?dataset a dcat:Dataset.
            ?dataset elseweb-data:hasManifestation	
                    [
                            elseweb-data:hasCapabilitiesDocumentURL ?capabilitiesURL;
                            elseweb-edac:hasJSONCapabilitiesDigestURL ?jsonURL
                    ]
    }